##################################################################
# leading-hyphen-remover-for-interval-tier.praat ( Written by Kyuchul Yoon  kyoon@ling.osu.edu
# Given an interval tier, this script goes through each interval one by one and removes any
#	leading hyphen.
##################################################################

form Specify files and folders
	word inFolder lab.TextGrid.after.LTS.scheme
	word inFileExt_(with_dot) .TextGrid
	natural tierToCorrect 2
	word outFolder lab.TextGrid.after.LTS.scheme.hyphen.corrected
endform

system mkdir 'outFolder$'

# Make a list of files
Create Strings as file list... fileList 'inFolder$'\*'inFileExt$'
Sort
numFiles = Get number of strings
pause 'numFiles' identified.  Continue?

# Loop through each file
for iFile to numFiles
	select Strings fileList
	fileName$ = Get string... iFile
	Read from file... 'inFolder$'\'fileName$'
	Rename... textgrid

	select TextGrid textgrid
	numIntervals = Get number of intervals... tierToCorrect

	# Loop through each interval
	for iInterval from 2 to (numIntervals-1)
		intervalText$ = Get label of interval... tierToCorrect iInterval
		lenIntervalText = length(intervalText$)
		firstLetter$ = left$(intervalText$, 1)
		if firstLetter$ = "-"
			newIntervalText$ = right$(intervalText$, (lenIntervalText-1))
			Set interval text... tierToCorrect iInterval 'newIntervalText$'
		endif
	endfor

	# Write the corrected textgrids to outFolder$
	Write to text file... 'outFolder$'\'fileName$'
	Remove
endfor

select Strings fileList
Remove

########### END OF SCRIPT #############